Delphi/Lazarus - LCD 20x4 Bricklet – Tinkerforge

- Getting Started
  - Primer
  - Tutorials
  - FAQ
- Hardware
  - Bricks
  - Bricklets
  - Master Extensions
  - Power Supplies
  - Accessories
  - Timeline
- Software
  - Brick Daemon (brickd)
  - Brick Viewer (brickv)
  - API Bindings
    - C/C++
    - C/C++ (iOS)
    - C#
    - C# (Windows Phone)
    - Delphi/Lazarus
      - Requirements
      - Installation
      - Testing an Example
      - API Reference and Examples
        - IP Connection
        - Bricks
        - Bricklets
          - Ambient Light Bricklet
          - Analog In Bricklet
          - Analog Out Bricklet
          - Barometer Bricklet
          - Color Bricklet
          - Current12 Bricklet
          - Current25 Bricklet
          - Distance IR Bricklet
          - Distance US Bricklet
          - Dual Button Bricklet
          - Dual Relay Bricklet
          - GPS Bricklet
          - Hall Effect Bricklet
          - Humidity Bricklet
          - Industrial Digital In 4 Bricklet
          - Industrial Digital Out 4 Bricklet
          - Industrial Dual 0-20mA Bricklet
          - Industrial Quad Relay Bricklet
          - IO-16 Bricklet
          - IO-4 Bricklet
          - Joystick Bricklet
          - LCD 16x2 Bricklet
          - LCD 20x4 Bricklet
            - Examples
              - Hello World
              - Button Callbacks
              - Unicode
            - API
              - Basic Functions
              - Advanced Functions
              - Callback Configuration Functions
              - Callbacks
              - Constants
          - LED Strip Bricklet
          - Line Bricklet
          - Linear Poti Bricklet
          - Moisture Bricklet
          - Motion Detector Bricklet
          - Multi Touch Bricklet
          - NFC/RFID Bricklet
          - Piezo Buzzer Bricklet
          - Piezo Speaker Bricklet
          - PTC Bricklet
          - Remote Switch Bricklet
          - Rotary Encoder Bricklet
          - Rotary Poti Bricklet
          - Segment Display 4x7 Bricklet
          - Solid State Relay Bricklet
          - Sound Intensity Bricklet
          - Temperature Bricklet
          - Temperature IR Bricklet
          - Tilt Bricklet
          - Voltage Bricklet
          - Voltage/Current Bricklet
    - Java
    - Java (Android)
    - JavaScript
    - LabVIEW
    - Mathematica
    - MATLAB/Octave
    - Perl
    - PHP
    - Python
    - Ruby
    - Shell
    - Visual Basic .NET
  - Firmwares and Plugins
  - Device Identifier
  - Source Code and Bug Tracking
  - Programming Interface
- Starter Kits
  - Weather Station
  - Hardware Hacking
  - Server Room Monitoring
  - Blinkenlights
  - Internet of Things
  - Camera Slider
- Embedded Boards
  - Raspberry Pi
- Specifications
  - Technical Data
  - TCP/IP Protocol
  - Modbus Protocol
  - Wireshark Dissector

# Delphi/Lazarus - LCD 20x4 Bricklet

This is the description of the Delphi/Lazarus API bindings for the LCD 20x4 Bricklet. General information and technical specifications for the LCD 20x4 Bricklet are summarized in its hardware description.

An installation guide for the Delphi/Lazarus API bindings is part of their general description.

## Examples

The example code below is Public Domain (CC0 1.0).

### Hello World

Download (ExampleHelloWorld.pas)

     1
     2
     3
     4
     5
     6
     7
     8
     9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    45
    46
    47
    48
    49
    50
    51
    52
    53

    program ExampleHelloWorld;

    {$ifdef MSWINDOWS}{$apptype CONSOLE}{$endif}
    {$ifdef FPC}{$mode OBJFPC}{$H+}{$endif}

    uses
      SysUtils, IPConnection, BrickletLCD20x4;

    type
      TExample = class
      private
        ipcon: TIPConnection;
        lcd: TBrickletLCD20x4;
      public
        procedure Execute;
      end;

    const
      HOST = 'localhost';
      PORT = 4223;
      UID = '9qL'; { Change to your UID }

    var
      e: TExample;

    procedure TExample.Execute;
    begin
      { Create IP connection }
      ipcon := TIPConnection.Create;

      { Create device object }
      lcd := TBrickletLCD20x4.Create(UID, ipcon);

      { Connect to brickd }
      ipcon.Connect(HOST, PORT);
      { Don't use device before ipcon is connected }

      { Turn backlight on }
      lcd.BacklightOn;

      { Write "Hello World" }
      lcd.WriteLine(0, 0, 'Hello World');

      WriteLn('Press key to exit');
      ReadLn;
      ipcon.Destroy; { Calls ipcon.Disconnect internally }
    end;

    begin
      e := TExample.Create;
      e.Execute;
      e.Destroy;
    end.

### Button Callbacks

Download (ExampleButtonCallbacks.pas)

     1
     2
     3
     4
     5
     6
     7
     8
     9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    45
    46
    47
    48
    49
    50
    51
    52
    53
    54
    55
    56
    57
    58
    59
    60
    61
    62
    63
    64

    program ExampleButtonCallbacks;

    {$ifdef MSWINDOWS}{$apptype CONSOLE}{$endif}
    {$ifdef FPC}{$mode OBJFPC}{$H+}{$endif}

    uses
      SysUtils, IPConnection, BrickletLCD20x4;

    type
      TExample = class
      private
        ipcon: TIPConnection;
        lcd: TBrickletLCD20x4;
      public
        procedure PressedCB(sender: TBrickletLCD20x4; const i: byte);
        procedure ReleasedCB(sender: TBrickletLCD20x4; const i: byte);
        procedure Execute;
      end;

    const
      HOST = 'localhost';
      PORT = 4223;
      UID = '9qL'; { Change to your UID }

    var
      e: TExample;

    { Callback functions for button status }
    procedure TExample.PressedCB(sender: TBrickletLCD20x4; const i: byte);
    begin
      WriteLn(Format('Pressed: %d', [i]));
    end;

    procedure TExample.ReleasedCB(sender: TBrickletLCD20x4; const i: byte);
    begin
      WriteLn(Format('Released: %d', [i]));
    end;

    procedure TExample.Execute;
    begin
      { Create IP connection }
      ipcon := TIPConnection.Create;

      { Create device object }
      lcd := TBrickletLCD20x4.Create(UID, ipcon);

      { Connect to brickd }
      ipcon.Connect(HOST, PORT);
      { Don't use device before ipcon is connected }

      { Register button status callbacks to procedure PressedCB and ReleasedCB }
      lcd.OnButtonPressed := {$ifdef FPC}@{$endif}PressedCB;
      lcd.OnButtonReleased := {$ifdef FPC}@{$endif}ReleasedCB;

      WriteLn('Press key to exit');
      ReadLn;
      ipcon.Destroy; { Calls ipcon.Disconnect internally }
    end;

    begin
      e := TExample.Create;
      e.Execute;
      e.Destroy;
    end.

### Unicode

Download (ExampleUnicode.pas)

      1
      2
      3
      4
      5
      6
      7
      8
      9
     10
     11
     12
     13
     14
     15
     16
     17
     18
     19
     20
     21
     22
     23
     24
     25
     26
     27
     28
     29
     30
     31
     32
     33
     34
     35
     36
     37
     38
     39
     40
     41
     42
     43
     44
     45
     46
     47
     48
     49
     50
     51
     52
     53
     54
     55
     56
     57
     58
     59
     60
     61
     62
     63
     64
     65
     66
     67
     68
     69
     70
     71
     72
     73
     74
     75
     76
     77
     78
     79
     80
     81
     82
     83
     84
     85
     86
     87
     88
     89
     90
     91
     92
     93
     94
     95
     96
     97
     98
     99
    100
    101
    102
    103
    104
    105
    106
    107
    108
    109
    110
    111
    112
    113
    114
    115
    116
    117
    118
    119
    120
    121
    122
    123
    124
    125
    126
    127
    128
    129
    130
    131
    132
    133
    134
    135
    136
    137
    138
    139
    140

    program ExampleUnicode;

    {$ifdef MSWINDOWS}{$apptype CONSOLE}{$endif}
    {$ifdef FPC}{$mode OBJFPC}{$H+}{$endif}

    uses
      SysUtils, IPConnection, BrickletLCD20x4;

    type
      TExample = class
      private
        ipcon: TIPConnection;
        lcd: TBrickletLCD20x4;
      public
        function WideStringToKS0066U(const text: WideString): string;
        procedure Execute;
      end;

    const
      HOST = 'localhost';
      PORT = 4223;
      UID = '555'; { Change to your UID }

    var
      e: TExample;

    function TExample.WideStringToKS0066U(const text: WideString): string;
    var i, codePoint: longint; w: word; c: char; ks0066u: string;
    begin
      i := 1;
      SetLength(ks0066u, 0);
      while (i <= Length(text)) do begin
        { WideString is UTF-16, handle surrogates }
        w := word(text[i]);
        if ((w >= $D800) and (w <= $DBFF)) then begin
          codePoint := $10000 + (w - $D800) * $400 + (w - $DC00);
          i := i + 2;
        end
        else begin
          codePoint := w;
          i := i + 1;
        end;
        { ASCII subset from JIS X 0201 }
        if ((codePoint >= $0020) and (codePoint <= $007E)) then begin
          { The LCD charset doesn't include '\' and '~', use similar characters instead }
          case codePoint of
            $005C: c := char($A4); { REVERSE SOLIDUS maps to IDEOGRAPHIC COMMA }
            $007E: c := char($2D); { TILDE maps to HYPHEN-MINUS }
            else   c := char(codePoint);
          end;
        end
        { Katakana subset from JIS X 0201 }
        else if ((codePoint >= $FF61) and (codePoint <= $FF9F)) then begin
          c := char(codePoint - $FEC0);
        end
        { Special characters }
        else begin
          case codePoint of
            $00A5: c := char($5C); { YEN SIGN }
            $2192: c := char($7E); { RIGHTWARDS ARROW }
            $2190: c := char($7F); { LEFTWARDS ARROW }
            $00B0: c := char($DF); { DEGREE SIGN maps to KATAKANA SEMI-VOICED SOUND MARK }
            $03B1: c := char($E0); { GREEK SMALL LETTER ALPHA }
            $00C4: c := char($E1); { LATIN CAPITAL LETTER A WITH DIAERESIS }
            $00E4: c := char($E1); { LATIN SMALL LETTER A WITH DIAERESIS }
            $00DF: c := char($E2); { LATIN SMALL LETTER SHARP S }
            $03B5: c := char($E3); { GREEK SMALL LETTER EPSILON }
            $00B5: c := char($E4); { MICRO SIGN }
            $03BC: c := char($E4); { GREEK SMALL LETTER MU }
            $03C2: c := char($E5); { GREEK SMALL LETTER FINAL SIGMA }
            $03C1: c := char($E6); { GREEK SMALL LETTER RHO }
            $221A: c := char($E8); { SQUARE ROOT }
            $00B9: c := char($E9); { SUPERSCRIPT ONE maps to SUPERSCRIPT (minus) ONE }
            $00A4: c := char($EB); { CURRENCY SIGN }
            $00A2: c := char($EC); { CENT SIGN }
            $2C60: c := char($ED); { LATIN CAPITAL LETTER L WITH DOUBLE BAR }
            $00F1: c := char($EE); { LATIN SMALL LETTER N WITH TILDE }
            $00D6: c := char($EF); { LATIN CAPITAL LETTER O WITH DIAERESIS }
            $00F6: c := char($EF); { LATIN SMALL LETTER O WITH DIAERESIS }
            $03F4: c := char($F2); { GREEK CAPITAL THETA SYMBOL }
            $221E: c := char($F3); { INFINITY }
            $03A9: c := char($F4); { GREEK CAPITAL LETTER OMEGA }
            $00DC: c := char($F5); { LATIN CAPITAL LETTER U WITH DIAERESIS }
            $00FC: c := char($F5); { LATIN SMALL LETTER U WITH DIAERESIS }
            $03A3: c := char($F6); { GREEK CAPITAL LETTER SIGMA }
            $03C0: c := char($F7); { GREEK SMALL LETTER PI }
            $0304: c := char($F8); { COMBINING MACRON }
            $00F7: c := char($FD); { DIVISION SIGN }
            $25A0: c := char($FF); { BLACK SQUARE }
            else   c := char($FF); { BLACK SQUARE }
          end
        end;
        { Special handling for 'x' followed by COMBINING MACRON }
        if (c = char($F8)) then begin
          if (ks0066u[Length(ks0066u) - 1] <> 'x') then begin
            c := char($FF); { BLACK SQUARE }
          end;
          if (Length(ks0066u) > 0) then begin
            SetLength(ks0066u, Length(ks0066u) - 1);
          end;
        end;
        ks0066u := ks0066u + c;
      end;
      result := ks0066u;
    end;

    procedure TExample.Execute;
    begin
      { Create IP connection }
      ipcon := TIPConnection.Create;

      { Create device object }
      lcd := TBrickletLCD20x4.Create(UID, ipcon);

      { Connect to brickd }
      ipcon.Connect(HOST, PORT);
      { Don't use device before ipcon is connected }

      { Turn backlight on }
      lcd.BacklightOn;

      { Write some strings using the WideStringToKS0066U function to map to the LCD charset }
      { NOTE: For the Free Pascal Compiler (and Lazarus) UTF8Decode is used to create a WideString.
              It assumes that your source file is UTF-8 encoded }
      lcd.WriteLine(0, 0, WideStringToKS0066U({$ifdef FPC}UTF8Decode{$endif}('Stromstärke: 17µA')));
      lcd.WriteLine(1, 0, WideStringToKS0066U({$ifdef FPC}UTF8Decode{$endif}('Temperatur:  23°C')));

      { Write a string directly including characters from the LCD charset }
      lcd.WriteLine(2, 0, 'Drehzahl:   750min' + char($E9));

      WriteLn('Press key to exit');
      ReadLn;
      ipcon.Destroy; { Calls ipcon.Disconnect internally }
    end;

    begin
      e := TExample.Create;
      e.Execute;
      e.Destroy;
    end.

## API

Since Delphi does not support multiple return values directly, we use the `out` keyword to return multiple values from a function.

All functions and procedures listed below are thread-safe.

### Basic Functions

constructor `TBrickletLCD20x4.``Create`(const uid: string; ipcon: TIPConnection)

  Creates an object with the unique device ID `uid`:

      lcd20x4 := TBrickletLCD20x4.Create('YOUR_DEVICE_UID', ipcon);

  This object can then be used after the IP Connection is connected (see examples above).

procedure `TBrickletLCD20x4.``WriteLine`(const line: byte; const position: byte; const text: string)

  Writes text to a specific line (0 to 3) with a specific position (0 to 19). The text can have a maximum of 20 characters.

  For example: (0, 7, "Hello") will write Hello in the middle of the first line of the display.

  The display uses a special charset that includes all ASCII characters except backslash and tilde. The LCD charset also includes several other non-ASCII characters, see the charset specification for details. The Unicode example above shows how to specify non-ASCII characters and how to translate from Unicode to the LCD charset.

procedure `TBrickletLCD20x4.``ClearDisplay`

  Deletes all characters from the display.

procedure `TBrickletLCD20x4.``BacklightOn`

  Turns the backlight on.

procedure `TBrickletLCD20x4.``BacklightOff`

  Turns the backlight off.

function `TBrickletLCD20x4.``IsBacklightOn`: boolean

  Returns true if the backlight is on and false otherwise.

### Advanced Functions

procedure `TBrickletLCD20x4.``SetConfig`(const cursor: boolean; const blinking: boolean)

  Configures if the cursor (shown as "_") should be visible and if it should be blinking (shown as a blinking block). The cursor position is one character behind the the last text written with `WriteLine`.

  The default is (false, false).

procedure `TBrickletLCD20x4.``GetConfig`(out cursor: boolean; out blinking: boolean)

  Returns the configuration as set by `SetConfig`.

function `TBrickletLCD20x4.``IsButtonPressed`(const button: byte): boolean

  Returns true if the button (0 to 2 or 0 to 3 since hardware version 1.2) is pressed. If you want to react on button presses and releases it is recommended to use the `OnButtonPressed` and `OnButtonReleased` callbacks.

procedure `TBrickletLCD20x4.``SetCustomCharacter`(const index: byte; const character: array [0..7] of byte)

  The LCD 20x4 Bricklet can store up to 8 custom characters. The characters consist of 5x8 pixels and can be addressed with the index 0-7. To describe the pixels, the first 5 bits of 8 bytes are used. For example, to make a custom character "H", you should transfer the following:

  - `character[0] = 0b00010001` (decimal value 17)
  - `character[1] = 0b00010001` (decimal value 17)
  - `character[2] = 0b00010001` (decimal value 17)
  - `character[3] = 0b00011111` (decimal value 31)
  - `character[4] = 0b00010001` (decimal value 17)
  - `character[5] = 0b00010001` (decimal value 17)
  - `character[6] = 0b00010001` (decimal value 17)
  - `character[7] = 0b00000000` (decimal value 0)

  The characters can later be written with `WriteLine` by using the characters with the byte representation 8 ("x08") to 15 ("x0F").

  You can play around with the custom characters in Brick Viewer version since 2.0.1.

  Custom characters are stored by the LCD in RAM, so they have to be set after each startup.

  New in version 2.0.1 (Plugin).

function `TBrickletLCD20x4.``GetCustomCharacter`(const index: byte): array [0..7] of byte

  Returns the custom character for a given index, as set with `SetCustomCharacter`.

  New in version 2.0.1 (Plugin).

procedure `TBrickletLCD20x4.``SetDefaultText`(const line: byte; const text: string)

  Sets the default text for lines 0-3. The max number of characters per line is 20.

  The default text is shown on the LCD, if the default text counter expires, see `SetDefaultTextCounter`.

  New in version 2.0.2 (Plugin).

function `TBrickletLCD20x4.``GetDefaultText`(const line: byte): string

  Returns the default text for a given line (0-3) as set by `SetDefaultText`.

  New in version 2.0.2 (Plugin).

procedure `TBrickletLCD20x4.``SetDefaultTextCounter`(const counter: longint)

  Sets the default text counter in ms. This counter is decremented each ms by the LCD firmware. If the counter reaches 0, the default text (see `SetDefaultText`) is shown on the LCD.

  This functionality can be used to show a default text if the controlling program crashes or the connection is interrupted.

  A possible approach is to call `SetDefaultTextCounter` every minute with the parameter 1000*60*2 (2 minutes). In this case the default text will be shown no later than 2 minutes after the controlling program crashes.

  A negative counter turns the default text functionality off.

  The default is -1.

  New in version 2.0.2 (Plugin).

function `TBrickletLCD20x4.``GetDefaultTextCounter`: longint

  Returns the current value of the default text counter.

  New in version 2.0.2 (Plugin).

function `TBrickletLCD20x4.``GetAPIVersion`: array [0..2] of byte

  Returns the version of the API definition (major, minor, revision) implemented by this API bindings. This is neither the release version of this API bindings nor does it tell you anything about the represented Brick or Bricklet.

function `TBrickletLCD20x4.``GetResponseExpected`(const functionId: byte): boolean

  Returns the response expected flag for the function specified by the function ID parameter. It is true if the function is expected to send a response, false otherwise.

  For getter functions this is enabled by default and cannot be disabled, because those functions will always send a response. For callback configuration functions it is enabled by default too, but can be disabled by `SetResponseExpected`. For setter functions it is disabled by default and can be enabled.

  Enabling the response expected flag for a setter function allows to detect timeouts and other error conditions calls of this setter as well. The device will then send a response for this purpose. If this flag is disabled for a setter function then no response is send and errors are silently ignored, because they cannot be detected.

  See `SetResponseExpected` for the list of function ID constants available for this function.

procedure `TBrickletLCD20x4.``SetResponseExpected`(const functionId: byte; const responseExpected: boolean)

  Changes the response expected flag of the function specified by the function ID parameter. This flag can only be changed for setter (default value: false) and callback configuration functions (default value: true). For getter functions it is always enabled and callbacks it is always disabled.

  Enabling the response expected flag for a setter function allows to detect timeouts and other error conditions calls of this setter as well. The device will then send a response for this purpose. If this flag is disabled for a setter function then no response is send and errors are silently ignored, because they cannot be detected.

  The following function ID constants are available for this function:

  - BRICKLET_LCD_20X4_FUNCTION_WRITE_LINE = 1
  - BRICKLET_LCD_20X4_FUNCTION_CLEAR_DISPLAY = 2
  - BRICKLET_LCD_20X4_FUNCTION_BACKLIGHT_ON = 3
  - BRICKLET_LCD_20X4_FUNCTION_BACKLIGHT_OFF = 4
  - BRICKLET_LCD_20X4_FUNCTION_SET_CONFIG = 6
  - BRICKLET_LCD_20X4_FUNCTION_SET_CUSTOM_CHARACTER = 11
  - BRICKLET_LCD_20X4_FUNCTION_SET_DEFAULT_TEXT = 13
  - BRICKLET_LCD_20X4_FUNCTION_SET_DEFAULT_TEXT_COUNTER = 15

procedure `TBrickletLCD20x4.``SetResponseExpectedAll`(const responseExpected: boolean)

  Changes the response expected flag for all setter and callback configuration functions of this device at once.

procedure `TBrickletLCD20x4.``GetIdentity`(out uid: string; out connectedUid: string; out position: char; out hardwareVersion: array [0..2] of byte; out firmwareVersion: array [0..2] of byte; out deviceIdentifier: word)

  Returns the UID, the UID where the Bricklet is connected to, the position, the hardware and firmware version as well as the device identifier.

  The position can be 'a', 'b', 'c' or 'd'.

  The device identifier numbers can be found here. There is also a constant for the device identifier of this Bricklet.

### Callback Configuration Functions

### Callbacks

Callbacks can be registered to receive time critical or recurring data from the device. The registration is done by assigning a procedure to an callback property of the device object:

>     procedure TExample.MyCallback(sender: TBrickletLCD20x4; const param: word);
>     begin
>       WriteLn(param);
>     end;

>     lcd20x4.OnExample := {$ifdef FPC}@{$endif}example.MyCallback;

The available callback property and their type of parameters are described below.

Note

Using callbacks for recurring events is always preferred compared to using getters. It will use less USB bandwidth and the latency will be a lot better, since there is no round trip time.

property `TBrickletLCD20x4.``OnButtonPressed`

      procedure(sender: TBrickletLCD20x4; const button: byte) of object;

  This callback is triggered when a button is pressed. The parameter is the number of the button (0 to 2 or 0 to 3 since hardware version 1.2).

property `TBrickletLCD20x4.``OnButtonReleased`

      procedure(sender: TBrickletLCD20x4; const button: byte) of object;

  This callback is triggered when a button is released. The parameter is the number of the button (0 to 2 or 0 to 3 since hardware version 1.2).

### Constants

const `BRICKLET_LCD_20X4_DEVICE_IDENTIFIER`

  This constant is used to identify a LCD 20x4 Bricklet.

  The `GetIdentity` function and the `OnEnumerate` callback of the IP Connection have a `deviceIdentifier` parameter to specify the Brick's or Bricklet's type.

The content of this page is licensed under Creative Commons Attribution 3.0 Unported License.